* Weapon Use Among Juvenile and Young Adult Arestees.


GET FILE='Directory\Path\NIBRS arrestee segment.sav'. 
RECODE arr_age (10 thru 17 = 1)(18 thru 25 = 2)(else = 0)INTO agegrp.
VALUE LABELS agegrp 1 'Juveniles' 2 'Young Adults'.
SELECT IF agegrp gt 0.
SORT CASES BY ori inc_num arrseq. 
SAVE OUTFILE = 'Directory\Path\arrestee_weapon.sav'
  /KEEP = ori inc_num arr_age agegrp.

GET FILE='Directory\Path\NIBRS offense segment.sav'
  /KEEP = ori inc_num offense weapon1 weapon2 weapon3 . 
SORT CASES BY ori inc_num offense.
COMPUTE msioff = 1.
IF (ori = LAG(ori) AND
    inc_num = LAG(inc_num))msioff = LAG(msioff) + 1.
SELECT IF (msioff = 1).
MATCH FILES /TABLE=*
 /FILE='Directory\Path\arrestee_weapon.sav'
 /BY ori inc_num. 

RECODE weapon1 to weapon3 
  ('11','12','13','14','15' = 1)
  ('40' = 2)
  ('30' = 3)
  ('20' = 4)
  ('95','99' = 6)
  (' ' = sysmis)
  (else = 5)INTO wpn1 to wpn3.

VALUE LABELS wpn1 to wpn3
  1 'All firearms'
  2 'Hands, feet, etc.'
  3 'Blunt object'
  4 'Knife'
  5 'All other weapons'
  6 'Unknown'.

TEMPORARY.
  VARIABLE LABELS agegrp '' .
TABLES
  /FORMAT BLANK MISSING('.')  
  /MRGROUP  $wpn ' '  wpn1 wpn2 wpn3
  /GBASE=CASES
  /FTOTAL= $t000002 "Total"
  /TABLE=$wpn + $t000002  BY agegrp > (STATISTICS)
  /STATISTICS
  count( $wpn( F5.0 ) 'Number')
  rpct( $wpn( PCT5.1 ) 'Pct.':agegrp ) 
  /TITLE  'Weapon Use Among Juvenile'
          'and Young Adult Arestees (1999)'.