GET FILE='Directory\Path\Incident 1999.sav'
SELECT IF (rob ge 1 and inc_yr = 1999).
SAVE OUTFILE = 'Directory\Path\Robbery Incident.sav'.
COMPUTE cleared = sum.1(clr_excp,clr_arr).
SORT CASES BY ori (A) inc_num (A) .
SAVE OUTFILE='Directory\Path\Robbery Incident.sav'
  /COMPRESSED.
GET FILE='Directory\Path\US99 offense segment.sav'.
SORT CASES BY ori (A) inc_num (A) .
SAVE OUTFILE='Directory\Path\US99 offense segment.sav'
  /COMPRESSED.
GET FILE='Directory\Path\Robbery Incident.sav'.
MATCH FILES /TABLE=*
 /FILE='Directory\Path\US99 offense segment.sav'
 /BY ori inc_num
 /DROP= att_comp bias crimact1 crimact2 crimact3 ibr_rec inc_date inc_dy
  inc_mo inc_yr meth_ent off_code prem_ent st_code.
SELECT IF (rob ge 1).

********************************************************************
* Incidents by Location NIBRS Reporting
********************************************************************. 
TEMPORARY.
VARIABLE LABELS inc_loc ' '.
GRAPH
  /BAR(SIMPLE)=COUNT BY inc_loc
  /MISSING=REPORT
  /TEMPLATE='Directory\Path\Robbery Location.sct'
  /TITLE= 'Incidents by Location' 'NIBRS Analysis'.

********************************************************************
* Robberies by Weapon NIBRS Reporting
********************************************************************. 
DO REPEAT weapon = weapon1 weapon2 weapon3/
  wpn = wpn1 wpn2 wpn3.
RECODE weapon (convert) INTO wpn.
END REPEAT.
VALUE LABELS wpn1 to wpn3
  11 'Firearm'
  12 'Handgun'
  13 'Rifle'
  14 'Shotgun'
  15 'Other Firearm'
  20 'Knife/Cutting Instrument'
  30 'Blunt Object'
  35 'Motor Vehicle'
  40 'Personal Weapons'
  50 'Poison'
  60 'Explosives'
  65 'Fire/lncendiary Device'
  70 'Drugs/Narcotics/Sleeping Pills'
  85 'Asphyxiation'
  90 'Other'
  95 'Unknown'
  99 'None'
  0 'Default'.
RECODE wpn1 (11 thru 15 = 1)
  (20 = 2)
  (30 = 3)
  (35 = 4)
  (40 = 5)
  (50 = 6)
  (60 = 7)
  (65 = 8)
  (70 = 9)
  (85 = 10)
  (90 = 11)
  (95 = 12)
  (99 = 13)INTO wpngrp.
IF (wpn2 ge 11 or wpn3 ge 11)wpngrp = 14.
VALUE LABELS wpngrp 
  1 'Firearm'
  2 'Knife'
  3 'Bl. Object'
  4 'MV'
  5 'Personal'
  6 'Poison'
  7 'Explosive'
  8 'Fire/lncend'
  9 'Drugs'
  10 'Asphyx'
  11 'Other'
  12 'Unknown'
  13 'No Wpn.'
  14 'Multi Wpn.'.
TEMPORARY.
VARIABLE LABELS wpngrp ' '.
GRAPH
  /BAR(SIMPLE)=COUNT BY wpngrp
  /MISSING=REPORT
  /TEMPLATE='Directory\Path\Robbery Weapons.sct'
  /TITLE= 'ROBBERIES by WEAPON' 'NIBRS Reporting'.
********************************************************************
* Types of Firearms NIBRS Reporting
********************************************************************. 
DO IF (wpngrp = 1).
RECODE weapon1 ('11' = 1)('12' = 2)('13' = 3)('14' = 4)('15' = 5)INTO firegrp.
IF (autowpn1 = 'A')firegrp = 6.
END IF.
VALUE LABELS firegrp
  1 'Firearm'
  2 'Handgun'
  3 'Rifle'
  4 'Shotgun'
  5 'Other Firearm'
  6 'Automatic'.
USE ALL.
COMPUTE filter_$=(wpngrp = 1).
VARIABLE LABEL filter_$ 'wpngrp = 1 (FILTER)'.
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
TEMPORARY.
VARIABLE LABELS firegrp ' '.
GRAPH
  /BAR(SIMPLE)=COUNT BY firegrp
  /MISSING=REPORT
  /TEMPLATE='Directory\Path\Robbery Weapons.sct'
  /TITLE= 'TYPES of FIREARMS' 'NIBRS Reporting'.
********************************************************************
* Types of Automatic Firearms NIBRS Reporting
********************************************************************. 
USE ALL.
COMPUTE filter_$=(wpngrp = 1 and firegrp = 6).
VARIABLE LABEL filter_$ 'wpngrp = 1 (FILTER)'.
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
VALUE LABELS weapon1
  '11' 'Firearm'
  '12' 'Handgun'
  '13' 'Rifle'
  '14' 'Shotgun'
  '15' 'Other Firearm'.
TEMPORARY.
VARIABLE LABELS weapon1 ' '.
GRAPH
  /BAR(SIMPLE)=COUNT BY weapon1
  /MISSING=REPORT
  /TEMPLATE='Directory\Path\Robbery Weapons.sct'
  /TITLE= 'TYPES of AUTOMATIC FIREARMS' 'NIBRS Reporting'.
********************************************************************
* By Multi-Weapon NIBRS Reporting
********************************************************************. 
DO IF (wpngrp = 14).
XSAVE OUTFILE = 'Directory\Path\multi-weapon1.sav'/
  keep = ori inc_num wpn1 autowpn1.
END IF.
DO IF (wpngrp = 14 and wpn2 gt 0).
XSAVE OUTFILE = 'Directory\Path\multi-weapon2.sav'/
  keep = ori inc_num wpn2 autowpn2.
END IF.
DO IF (wpngrp = 14 and wpn3 gt 0).
XSAVE OUTFILE = 'Directory\Path\multi-weapon3.sav'/
  keep = ori inc_num wpn3 autowpn3.
END IF.
EXECUTE.
GET FILE = 'Directory\Path\multi-weapon1.sav'.
ADD FILES /FILE=*
 /RENAME  (wpn1 autowpn1=wpn autowpn)
 /FILE='Directory\Path\multi-weapon2.sav'
 /RENAME  (wpn2 autowpn2=wpn autowpn)
 /FILE='Directory\Path\multi-weapon3.sav'
 /RENAME  (wpn3 autowpn3=wpn autowpn).
EXECUTE.
RECODE wpn (11 thru 15 = 1)
  (20 = 2)
  (30 = 3)
  (35 = 4)
  (40 = 5)
  (50 = 6)
  (60 = 7)
  (65 = 8)
  (70 = 9)
  (85 = 10)
  (90 = 11)
  (95 = 12)
  (99 = 13)INTO wpngrp.
VALUE LABELS wpngrp 
  1 'Firearm'
  2 'Knife'
  3 'Bl. Object'
  4 'MV'
  5 'Personal'
  6 'Poison'
  7 'Explosive'
  8 'Fire/lncend'
  9 'Drugs'
  10 'Asphyx'
  11 'Other'
  12 'Unknown'
  13 'No Wpn.'.
TEMPORARY.
VARIABLE LABELS wpngrp ' '.
GRAPH
  /BAR(SIMPLE)=COUNT BY wpngrp
  /MISSING=REPORT
  /TEMPLATE='Directory\Path\Robbery Weapons.sct'
  /TITLE= 'MULTI-WEAPONS' 'NIBRS Reporting'.

********************************************************************
* By Multi-Weapon (Firearms) NIBRS Reporting
********************************************************************. 
DO IF (wpngrp = 1).
RECODE wpn (11 = 1)(12 = 2)(13 = 3)(14 = 4)(15 = 5)INTO firegrp.
IF (autowpn = 'A')firegrp = 6.
END IF.
VALUE LABELS firegrp
  1 'Firearm'
  2 'Handgun'
  3 'Rifle'
  4 'Shotgun'
  5 'Other Firearm'
  6 'Automatic'.
USE ALL.
COMPUTE filter_$=(wpngrp = 1).
VARIABLE LABEL filter_$ 'wpngrp = 1 (FILTER)'.
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
TEMPORARY.
VARIABLE LABELS firegrp ' '.
GRAPH
  /BAR(SIMPLE)=COUNT BY firegrp
  /MISSING=REPORT
  /TEMPLATE='Directory\Path\Robbery Weapons.sct'
  /TITLE= 'MULTI-WEAPON TYPES of FIREARMS' 'NIBRS Reporting'.

********************************************************************
* TIME of DAY and NUMBER CLEARED NIBRS Reporting
********************************************************************. 
GET FILE='Directory\Path\Robbery Incident.sav'.
COMPUTE cleared = 0.
IF(clr_excp = 1 or clr_arr = 1)cleared = 1.
RECODE inc_hr (sysmis = 99).
IF (rptdate = 'R')inc_hr = 99.
VALUE LABELS cleared
  0 'Not cleared'
  1 'Cleared'.
VALUE LABELS inc_hr
  0 'Midnight-12:59'
  1 '1-1:59 a.m.'
  2 '2-2:59 a.m.' 
  3 '3-3:59 a.m.' 
  4 '4-4:59 a.m.' 
  5 '5-5:59 a.m.' 
  6 '6-6:59 a.m.' 
  7 '7-7:59 a.m.' 
  8 '8-8:59 a.m.' 
  9 '9-9:59 a.m.' 
  10 '10-10:59 a.m.' 
  11 '11-11:59 a.m.' 
  12 'Noon-12:59 p.m.' 
  13 '1-1:59 p.m.' 
  14 '2-2:59 p.m.' 
  15 '3-3:59 p.m.' 
  16 '4-4:59 p.m.' 
  17 '5-5:59 p.m.' 
  18 '6-6:59 p.m.' 
  19 '7-7:59 p.m.' 
  20 '8-8:59 p.m.' 
  21 '9-9:59 p.m.' 
  22 '10-10:59 p.m.' 
  23 '11-11:59 p.m.'
  99 'Unk. Time'.
USE ALL.
COMPUTE filter_$=(inc_hr < 99).
VARIABLE LABEL filter_$ 'inc_hr < 99 (FILTER)'.
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
TEMPORARY.
VARIABLE LABELS inc_hr ' ' /
   cleared ' '. 
GRAPH
  /BAR(STACK)=COUNT BY inc_hr BY cleared
  /MISSING=REPORT
  /TEMPLATE='Directory\Path\Robbery Time of Day.sct'
  /TITLE= 'TIME of DAY and NUMBER CLEARED' 'NIBRS Reporting'.
SAVE OUTFILE='Directory\Path\Robbery Incident.sav'
  /COMPRESSED.

********************************************************************
* TIME of DAY and PERCENT CLEARED NIBRS Reporting
********************************************************************. 
AGGREGATE /OUTFILE=*
 /BREAK=inc_hr
 /cleared ' ' = SUM(cleared)
 /number ' ' = N(offense).
COMPUTE pct_clrd = ((cleared/number)*100).
FORMATS pct_clrd(f8.1).
USE ALL.
COMPUTE filter_$=(inc_hr < 99).
VARIABLE LABEL filter_$ 'inc_hr < 99 (FILTER)'.
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
TEMPORARY.
VARIABLE LABELS inc_hr ' ' /
   pct_clrd ' '. 
GRAPH
  /LINE(SIMPLE)=MEAN(pct_clrd) BY inc_hr
  /MISSING=REPORT
  /TEMPLATE='Directory\Path\Robbery Time of Day2.sct'
  /TITLE= 'TIME of DAY and PERCENT CLEARED' 'NIBRS Reporting'.